☰

現在の行をcsvの次の行と比較し、Unixスクリプトで列の違いを表示する方法

tag-icon • tag-icon shell-script awk
現在の行をcsvの次の行と比較し、Unixスクリプトで列の違いを表示する方法

ファイル.csv

ABC,EFG,22  
XYZ,MNO,24  
XYZ,MNO,228
SPOT,ID,NUMBER
SPOT,ID,VARCHAR2
INF,SUMMARY,VARCHAR2
INF,SUMMARY,NUMBER

最初と2番目の行を比較して、ABCとXYZが異なることを示したいと思います。 2行目と3行目を比較すると、24が前の値になり、228が新しい値になります。

他の場合は、列ごとに同様の比較を実行し、値を印刷します。現在の行を前のレコードと比較する際に問題があります。

同じラインで比較してみることができます。以下は何とか同じ行で動作しますが、前の行を確認することはできません。

awk -F: '{if(!($1==$2||$2==$3||$3==$1))printf("%s","not ");print"matched",$0}' file.csv

また、他の変数に値を代入して読み、比較するためにwhileループを試しました。

x=""
while IFS= , read -r a b c
do
 if [a == x]]
then
 echo "$a"
x=$a
done < input.csv

答え1

$ cat tst.awk
BEGIN { FS="," }
NR > 1 {
    if (p[0] != $0) {
        printf "\nLine %d (%s) != %d (%s)\n", NR-1, p[0], NR, $0
    }
    for (i=1; i<=NF; i++) {
        if (p[i] != $i) {
            printf "\tField %d.%d (%s) != %d.%d (%s)\n", NR-1, i, p[i], NR, i, $i
        }
    }
}
{ split($0,p); p[0]=$0 }

。

$ awk -f tst.awk file.csv

Line 1 (ABC,EFG,22) != 2 (XYZ,MNO,24)
        Field 1.1 (ABC) != 2.1 (XYZ)
        Field 1.2 (EFG) != 2.2 (MNO)
        Field 1.3 (22) != 2.3 (24)

Line 2 (XYZ,MNO,24) != 3 (XYZ,MNO,228)
        Field 2.3 (24) != 3.3 (228)

Line 3 (XYZ,MNO,228) != 4 (SPOT,ID,NUMBER)
        Field 3.1 (XYZ) != 4.1 (SPOT)
        Field 3.2 (MNO) != 4.2 (ID)
        Field 3.3 (228) != 4.3 (NUMBER)

Line 4 (SPOT,ID,NUMBER) != 5 (SPOT,ID,VARCHAR2)
        Field 4.3 (NUMBER) != 5.3 (VARCHAR2)

Line 5 (SPOT,ID,VARCHAR2) != 6 (INF,SUMMARY,VARCHAR2)
        Field 5.1 (SPOT) != 6.1 (INF)
        Field 5.2 (ID) != 6.2 (SUMMARY)

Line 6 (INF,SUMMARY,VARCHAR2) != 7 (INF,SUMMARY,NUMBER)
        Field 6.3 (VARCHAR2) != 7.3 (NUMBER)

関連情報