zshで配列インデックスを繰り返す方法は？

Question 1

zsh配列は、他のほとんどのシェルや言語の配列などの一般的な配列であり、キーが正の整数（希少配列とも呼ばれる）に制限されるという点で、ksh / bashの連想配列とは異なります。zsh連想配列には別の変数型があります（キーは0バイト以上のランダムシーケンスです）。

したがって、通常の配列のインデックスは常に1から配列サイズまでの整数です（ksh互換性が有効になっていない場合、配列インデックスは1ではなく0から始まります）。

だから：

typeset -a array
array=(a 'b c' '')
for ((i = 1; i <= $#array; i++)) print -r -- $array[i]

ただし、通常はインデックスではなく配列メンバを繰り返します。

for i ("$array[@]") print -r -- $i

（この"$array[@]"構文は逆$arrayであり、空の要素を保持します。）

または：

print -rC1 -- "$array[@]"

すべての要素をコマンドに渡します。

ここでループを繰り返します。連想配列、構文は次のとおりです。

typeset -A hash
hash=(
  key1  value1
  key2  value2
  ''    empty
  empty ''
)
for key ("${(@k)hash}") printf 'key=%s value=%s\n' "$key" "$hash[$key]"

（@空の要素を保存するには、内部引用符を再利用してください）。

以下を使用して、キーと値をコマンドに渡すこともできます。

printf 'key=%s value=%s\n' "${(@kv)hash}"

Bourne型シェルのさまざまな配列設計の詳細については、以下を参照してください。アレイのテストシェルのサポート

Answer

zsh配列は、他のほとんどのシェルや言語の配列などの一般的な配列であり、キーが正の整数（希少配列とも呼ばれる）に制限されるという点で、ksh / bashの連想配列とは異なります。zsh連想配列には別の変数型があります（キーは0バイト以上のランダムシーケンスです）。