☰

最初のN行を繰り返すあまり似ていないポケットベル

tag-icon • tag-icon command-line less pager
最初のN行を繰り返すあまり似ていないポケットベル

less表示されているすべてのページでプログラムに最初の行（または最初の2行）を繰り返す方法はありますか？

これを行うことができる他のポケットベルはありますか？

これはデータベーステーブルナビゲーションのためのキラーアプリになりmysqlますpsql。gqlplus

下のスクリーンショットを参照このページ。ヘッダー行+水平ASCII列を繰り返したい。

答え1

Vimを使用するソリューションがあります。

まず、ほとんどのタスクを実行するVimマクロが必要です。次の場所に保存してください~/.vim/plugin/less.vim。

" :Less
" turn vim into a pager for psql aligned results 
fun! Less()
  set nocompatible
  set nowrap
  set scrollopt=hor
  set scrollbind
  set number
  execute 'above split'
  " resize upper window to one line; two lines are not needed because vim adds separating line
  execute 'resize 1'
  " switch to lower window and scroll 2 lines down 
  wincmd j
  execute 'norm! 2^E'
  " hide statusline in lower window
  set laststatus=0
  " hide contents of upper statusline. editor note: do not remove trailing spaces in next line!
  set statusline=\  
  " arrows do scrolling instead of moving
  nmap ^[OC zL
  nmap ^[OB ^E
  nmap ^[OD zH
  nmap ^[OA ^Y
  nmap <Space> <PageDown>
  " faster quit (I tend to forget about the upper panel)
  nmap q :qa^M
  nmap Q :qa^M
endfun
command! -nargs=0 Less call Less()

次に、ポケットベルをシミュレートするには、vimを呼び出して次のことを行う必要があります。

  • 標準入力を読む
  • しかし、コマンドラインに引数が与えられたら、そこから何でも読んでください。
  • 読み取り専用モードでの作業
  • すべての初期化スクリプトをスキップして、代わりに上記で定義されたLessマクロを実行してください。

私はこれをヘルパースクリプトでまとめました~/bin/vimpager。

#!/bin/bash
what=-
test "$@" && what="$@"
exec vim -u NONE -R -S ~/.vim/plugin/less.vim -c Less $what

スクリプトを実行可能にするために使用されますchmod +x ~/bin/vimpager。

第三に、psqlのポケットベルを書き換える必要があります。PAGERpsqlだけでなく他のプログラムにも影響を与えるため、グローバルに変数を設定しないでください。代わりに、以下をファイルに追加してください~/.psqlrc。

\setenv PAGER ~/bin/vimpager

バラより！プロファイルを再読み込みすると、次のように期待どおりに機能する結果を楽しむことができます（垂直方向と水平方向のナビゲーション用の矢印キー）。活動中のウィンパー。さらに、必要に応じてVimのすべての機能を使用できます。

答え2

試してみましたか？SQLモードEmacs/XEmacsからか。

moreorほど使いやすくはありませんが、less結果を垂直方向と水平方向にスクロールするときにヘッダー行を残す必要があるという要件を満たしています。

答え3

これは次から大きく借りたものです。受け入れられた答え、しかし、追加されました...

  • すばやくスクロール
  • 誤ってタイトルをスクロールすることはありません。
  • フレーズ強調（一部クレジットここに属する)
    • 正/負、日付、時刻、NULL真/偽（そしてT / F、Y / N、はい/いいえ）
    • 行番号（パイプ文字の前に行番号がある場合）
  • ヘルプテキスト
  • 埋め込み Vim サポートWindows用Git
  • 標準入力バッファが変更された場合、ビューを更新することを脅かさないでください。

を使用しないため、特定の出力に合わせて一部の部分を調整する必要がありますpsql。私の目的によってヘルパー機能も少し異なりますが、答えが受け入れられました。

入力サンプル

  | ID |   First   |     Last     | Member | Balance |
--+----+-----------+--------------+--------+---------+
 1|  4 | Tom       | Hanks        | False  |    0.00 |
 2| 12 | Susan     | Patterson    | True   |   10.00 |
 3| 23 | Harriet   | Langford-Wat | False  |    0.00 |
 4|  8 | Jerry     |     NULL     | True   | -382.94 |
[… More rows …]
10| 87 | Horace    | Weaver       | False  |   47.52 |

パスワード

" :HeadPager
" Turn vim into a pager with a header row
" Adapted from https://unix.stackexchange.com/a/27840/143088
fun! HeadPager()
    " If you didn't get three lines, shortcut out
    if line('$') < 3
        set nocompatible
        nmap <silent> q :qa!<c-M>
        nmap <silent> Q :qa!<c-M>
        return
    endif

    set noswapfile
    set nocompatible
    set nowrap
    set scrollopt=hor
    set scrollbind

    " Hide statusline in lower window
    set laststatus=0
    " Explain mapped chars in status line.
    set statusline=\ \ \ Q\ to\ quit\.\ Arrows\ or\ mousewheel\ to\ scroll\.\ \(Vim\ commands\ work\,\ too\.\)

    " Delete/copy header lines
    silent execute '1,2d'

    " Split screen with new buffer (opens at top)
    execute 'new'

    " Switch to upper split
    wincmd k

    " Paste the header over the blank line
    execute 'norm! Vp'

    " Header highlighting
    syn match Pipe "|"
    hi def Pipe ctermfg=blue
    syn match Any /[^|]\+/
    hi def Any ctermfg=yellow

    " Switch back to lower split for scrolling
    wincmd j

    " Set lower split height to maximum
    execute "norm! \<c-W>_"

    " Syntax highlighting
    syn cluster CellContents contains=None
    syn match Pipe "|" contained nextgroup=@CellContents skipwhite
    hi def Pipe ctermfg=blue

    " Start with newline or |. End right before next | or EOL
    syn region Cell start=/\v(^|\|)\s*/ end=/\v(\||$)\@=/ contains=LineNumber,Pipe

    syn match NumPos /\v\+?\d+(,?\d{3})*\.?\d*\ze *(\||$)\@=/ contained
    syn match NumNeg   /\v-\d+(,?\d{3})*\.?\d*\ze *(\||$)\@=/ contained
    syn match NumZero         /\v[+-]?0+\.?0*\ze *(\||$)\@=/  contained
    hi def NumPos ctermfg=cyan
    hi def NumNeg ctermfg=red
    hi def NumZero ctermfg=NONE
    syn cluster CellContents add=NumPos,NumNeg,NumZero

    syn match DateVal /\v\d{4}-\d{2}-\d{2}/ contained nextgroup=TimeVal skipwhite
    syn match TimeVal /\v\d{1,2}:\d{2}(:\d{2})?(\.\d+)?(Z| ?\c[AP]M)?\ze *(\||$)\@=/ contained
    hi def DateVal ctermfg=magenta
    hi def TimeVal ctermfg=magenta
    syn cluster CellContents add=DateVal,TimeVal

    syn match TrueVal /\v\c(t(rue)?|y(es)?)\ze *(\||$)\@=/ contained
    syn match FalseVal /\v\c(f(alse)?|no?)\ze *(\||$)\@=/ contained
    hi def TrueVal ctermfg=green
    hi def FalseVal ctermfg=red
    syn match NullVal /\v\cnull?\ze *(\||$)\@=/ contained
    hi def NullVal ctermbg=gray ctermfg=black
    syn cluster CellContents add=TrueVal,FalseVal,NullVal

    syn match LineNumber /^ *\d\+/ contained
    hi def LineNumber ctermfg=yellow

    " Arrows do scrolling instead of moving
    nmap <silent> <Up> 3<c-Y>
    nmap <silent> <Down> 3<c-E>
    nmap <silent> <Left> zH
    nmap <silent> <Right> zL
    nmap <Space> <PageDown>
    " Faster quit (I tend to forget about the upper panel)
    nmap <silent> q :qa!<c-M>
    nmap <silent> Q :qa!<c-M>

    " Ignore external updates to the buffer
    autocmd! FileChangedShell */fd/*
    autocmd! FileChangedRO */fd/*
endfun
command! -nargs=0 HeadPager call HeadPager()

答え4

「前方」の前に数字を追加すると、全長ではなくN行がスクロールします。したがって、ターミナルウィンドウに40行がある場合、38fstartと入力すると、最後の「ページ」の最後の2行だけが残り、38行だけスクロールします。マンページから：

   SPACE or ^V or f or ^F
          Scroll forward N  lines,  default  one  window  (see  option  -z
          below).   If  N  is  more  than  the screen size, only the final
          screenful is displayed.  Warning: some systems use ^V as a  spe‐
          cial literalization character.

   z      Like  SPACE,  but  if  N is specified, it becomes the new window
          size.

   b or ^B or ESC-v
          Scroll backward N lines,  default  one  window  (see  option  -z
          below).   If  N  is  more  than  the screen size, only the final
          screenful is displayed.

関連情報