☰

値1が正確に一致すると、2つのファイルの値2と一致します。

tag-icon • tag-icon bash shell-script awk array
値1が正確に一致すると、2つのファイルの値2と一致します。

リストを含むファイルが2つあります。列 1 はユーザー ID、列 2 は関連値です。

# cat file1
e3001 75
n5244 30
w1453 500

#cat file2
d1128 30
w1453 515
n5244 30
e3001 55

考慮すべき事項。

  1. 両方のファイルの userId が正しくソートされていない可能性があります。
  2. ファイルの userId 数は異なる場合があります。

必須

  • まず、file1：column1のuserIdはfile2：column1のUserIdと一致する必要があります。
  • 次に、file1：column2の値をfile2：column2の値と比較します。
  • 値に違いがある場所を印刷します。および追加のuserId（存在する場合）

出力：

e3001 has differnece, file1 value: 75 & file2 value: 55
w1453 has differnece, file1 value: 500 & file2 value: 515
d1128 is only present in filename: file1|file2

1liner-awkまたはbashループソリューションへようこそ。

ループを試していますが、ゴミが吐き出しています。論理エラーがあるようです。

#!/usr/bin/env bash

## VARIABLES
FILE1=file1
FILE2=file2
USERID1=(`awk -F'\t' '{ print $1 }' ${FILE1}`)
USERID2=(`awk -F'\t' '{ print $1 }' ${FILE2}`)
USERDON1=(`awk -F'\t' '{ print $2 }' ${FILE1}`)
USERDON2=(`awk -F'\t' '{ print $2 }' ${FILE2}`)

for user in ${USERID1[@]}
do
    for (( i = 0; i < "${#USERID2[@]}"; i++ ))
    #for user in ${USERID2[@]}
    do
        if [[ ${USERID1[$user]} == ${USERID2[i]} ]]
        then
            echo ${USERID1[$user]} MATCHES BALANCE FROM ${FILE1}: ${USERDON1[$i]} WITH BALANCE FROM ${FILE2}: ${USERDON2[$i]}
        else
            echo ${USERID1[$user]} 
        fi
    done
done

以下は、Linuxボックスから直接コピーしたファイルです。タブで区切られていますが、私が知っている限り、awkはタブも使用できます。

#cat file1
e3001   55
n5244   30
w1453   515

答え1

さて、言うと、あなたの台本は風光明媚な道を選びます。簡単な方法はどうですかawk？良い

awk '
NR==FNR         {ARR[$1] = $2
                 F1      = FILENAME
                 next
                }
($1 in ARR)     {if ($2 != ARR[$1]) print $1 " has difference," \
                                          F1 " value: " ARR[$1] \
                                          " & " FILENAME " value: " $2 
                 delete ARR[$1]
                 next
                }
                {print $1 " is only present in filename: " FILENAME
                }
END             {for (a in ARR) print a " is only present in filename: " F1
                }
' file[12]
d1128 is only present in filename: file2
w1453 has difference, file1 value: 500 & file2 value: 515
e3001 has difference, file1 value: 75 & file2 value: 55

file1のすべての内容を配列として読み込み、file2の各行について配列$1インデックスを確認し、違いがある場合は印刷し（存在しない）、配列delete要素を保存します（deleteおそらくいくつかのawkに実装がありません。btw）。存在しない場合は、それに応じて印刷してください。このENDセクションでは、残りの配列要素はすべてfile1にのみ存在するため、印刷されます。

答え2

コメントは自明です。

awk '
    BEGIN {file1 = ARGV[1]; file2 = ARGV[2]}

    # Load all file1 contents
    NR == FNR {map[$1] = $2; next}
    
    # If $1 is not in m then this key is unique to file2
    !($1 in map) {uniq[$1]; next}

    # If $1 is in m and the value differs there are delta
    # between the two files. Save it.
    $1 in map && map[$1] != $2 {diff[$1] = $2; next}

    # The two files have all the same data.
    {delete map[$1]}

    END {
        # Anything is in diff are in both files but
        # with different values
        for ( i in diff )
            print i, "has difference,", file1, "value:", map[i], "&", file2, "value:", diff[i]

        # Anything is still in m is only in file 1
        for ( i in map )
            if (!(i in diff))
                print i, "is only present in filename :", file1

        # Anything is in uniq is unique to file2
        for ( i in uniq )
            print i, "is only present in filename :", file2
    }
' file1 file2

答え3

シェルはこの種の作業にひどいツールです。また、通常、シェルスクリプトではシェル変数に大文字を使用しないでください。グローバル環境シェル変数は慣例的にすべて大文字であるため、命名競合が発生し、デバッグが困難な問題が発生する可能性があります。最後に、スクリプトはファイルを4回（！）読み取る必要があります。それからデータ処理。

しかし、別の奇妙なアプローチがあります（正直に言うとルーディックス良いですが、すでにこの記事を書いているので、とにかく投稿します）：

$ awk '{
  if(NR==FNR) {
    fn1=FILENAME;
    f1[$1]=$2;
    next
  }
  f2[$1]=$2;
  if($1 in f1){
    if($2 != f1[$1]){
      printf "%s is different; %s value: %s & %s value: %s\n", \
             $1,fn1,$2,FILENAME,f1[$1]
    }
  }
  else{
    print $1,"is only present in filename:", FILENAME
  }
}
END{
  for(id in f1){
    if( !(id in f2) ){print id,"is only present in afilename:",fn1}
  }
}' file1 file2
d1128 is only present in filename: file2
w1453 is different; file1 value: 515 & file2 value: 500
e3001 is different; file1 value: 55 & file2 value: 75

答え4

awk 'function printUniq(Id, fName){
         printf("%s is only present in filename: %s\n", Id, fName)
}

{ fileName[nxtinput+0]=FILENAME }
!nxtinput{ Ids[$1]=$2; next }

($1 in Ids){ if($2!=Ids[$1])
                 printf ("%s has difference, %s value: %s & %s value: %s\n",\
                 $1, fileName[0], Ids[$1], fileName[1], $2);
             delete Ids[$1];
             next
}
{ printUniq($1, fileName[1]) }
END{ for(id in Ids) printUniq(id, fileName[0]) }' file1 nxtinput=1 file2

関連情報