目的

Question 1

私はラッパー関数を使用します。これを.bashrcに追加できます（テストされていません）。

mv () {
    case $1 in
        -*i*) # ok, used `mv -i ...`: invoke the mv command, passing all args
            command mv "$@"
            ;;
        *)
            echo "hey, use 'mv -i'" >&2
            false
            ;;
    esac
}

Answer

私はラッパー関数を使用します。これを.bashrcに追加できます（テストされていません）。

mv () {
    case $1 in
        -*i*) # ok, used `mv -i ...`: invoke the mv command, passing all args
            command mv "$@"
            ;;
        *)
            echo "hey, use 'mv -i'" >&2
            false
            ;;
    esac
}

Question 2

しかし、@glennJackmanのアプローチ-最初の引数が次から始まり、含まれていることを確認するラッパーを使用すると、ほとんどの一般的なケースでは十分ですが、場合によってはi失敗します。

邪魔しますmv --help（--version含まれていません-i）。
-iでは検出できません（またはmv -v -i a b環境にisがない場合、mv a b -iGNUは許可します）。mvPOSIXLY_CORRECT
GNUは含まれていませんmv --interactive// mv --in...mv --i
-i欠けているものを見逃しmv --no-target-dir a bたりmv -Tdir file...

ラッパーがこれらすべてのケースをカバーするには、同じ方法でオプションを解決する必要がありますmv。両方の実装では、同じ方法でオプションを解析しません。mv同じ実装バージョン間にも違いがあります。

GNU実装mv（およびほとんどのユーティリティ）がそれを解析するために使用するオプションですgetopt_long()。

同じ引数を使用してラッパーをgetopt_long()呼び出せる場合は、ソートされます。これは2つの質問を残します。

getopt_long()シェルでインターフェースを見つける必要があります
mv私たちはどちらが伝わるのかを知る必要があります。getopt_long()

GNU/Linux システムを使用する場合は、いくつかの可能な方法があります。

getopt_long()GNUツールボックスにはシェルCLIはありませんがutil-linux、：と一緒に使用するgetoptユーティリティがあります。-o-l

GNU / Linuxでは、GNUユーティリティはgetopt_long()libcでこの関数を呼び出します。これはGNU libcであるため、トレースltraceライブラリの呼び出しを使用して解析オプションの呼び出しを確認できますgetopt_long()。mv

$ ltrace -e getopt_long mv -:
mv->getopt_long(2, 0x7ffcf7febd68, "bfint:uvS:TZ", 0x5650dd02fb20, nilmv: invalid option -- ':'
)                           = 63
Try 'mv --help' for more information.
+++ exited (status 1) +++

（-:保証は無効なオプションの場合）

私たちは単純なオプションだけを見たので十分ではありません。しかし、ltraceそこからパラメータをデコードするように設定することも、long_options私たちが気にしないパラメータを隠すように設定することもできます。

概念証明として、以下は、sh呼び出し前に-i/ --interactive（または--help/ --version）またはその略語を確認するラッパー関数の互換コードを出力するzshスクリプトですmv。

#! /bin/zsh -
set -o extendedglob
die() {
  print -ru2 -- "$@"
  exit 1
}

for cmd do
  getopt_long_call=$(
    ltrace -F/dev/fd/3 3<<'EOF' -o/dev/fd/4 4>&1 > /dev/null 2>&1 -s 999 -A999 -e getopt_long "$cmd" -:
int getopt_long(hide(int),hide(addr),string,array(struct(string,int,hide(int*),hide(int)),zero),hide(int*));
EOF
  )
  getopt_long_call=${getopt_long_call%%$'\n'*}

  [[ $getopt_long_call = (#b)[^\"]#'getopt_long("'([^\"]#)'", [ '(*)' ]) = '<-> ]] ||
    die "Can't determine what getopt_long call $cmd does"

  short_opts=() long_opts=()
  : ${match[1]//(#m)?:#/${short_opts[1+$#short_opts]::=$MATCH}}
  : ${match[2]//(#b)'{ "'([^\"]#)'", '(<->)' }'/${long_opts[1+$#long_opts]::=$match[1]${(l($match[2])(:))}}}
  opts_with_args=(-${(M)^short_opts:#*:} --${(M)^long_opts:#*:})
  opts_with_args=(${opts_with_args%%:#})

  print -r -- $cmd'() {
  (
    opt=$(getopt -qo '${(j[]qq)short_opts}' '${(qq)long_opts/#/-l}' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
        (-i | --interactive | --version | --help) exit;;
        (--) printf >&2 "%s\n" "Please run '$cmd' with -i/--interactive"
             exit 1;;
        ('${(j[ | ])${(qq)opts_with_args}}') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command '$cmd' "$@"
}'
done

たとえば、私のシステムでは、that-script mv rm出力は次のようになります。

mv() {
  (
    opt=$(getopt -qo 'bfint:uvS:TZ' '-lbackup::' '-lcontext' '-lforce' '-linteractive' '-lno-clobber' '-lno-target-directory' '-lstrip-trailing-slashes' '-lsuffix:' '-ltarget-directory:' '-lupdate' '-lverbose' '-lhelp' '-lversion' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
    (-i | --interactive | --version | --help) exit;;
    (--) printf >&2 "%s\n" "Please run mv with -i/--interactive"
         exit 1;;
    ('-t' | '-S' | '--backup' | '--suffix' | '--target-directory') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command mv "$@"
}
rm() {
  (
    opt=$(getopt -qo 'dfirvIR' '-lforce' '-linteractive::' '-lone-file-system' '-lno-preserve-root' '-lpreserve-root::' '-l-presume-input-tty' '-lrecursive' '-ldir' '-lverbose' '-lhelp' '-lversion' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
    (-i | --interactive | --version | --help) exit;;
    (--) printf >&2 "%s\n" "Please run rm with -i/--interactive"
         exit 1;;
    ('--interactive' | '--preserve-root') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command rm "$@"
}

あなたはこれを行います：

eval "$(that-script mv rm)"

シェルの対話型モード設定（~/.zshrc、~/.bashrc...）。

対応するラッパーを定義します。それから：

$ rm a -i
rm: remove regular file 'a'? n
$ rm a --int
rm: remove regular file 'a'? n
$ mv --version
mv (GNU coreutils) 8.32
Copyright (C) 2020 Free Software Foundation, Inc.
License GPLv3+: GNU GPL version 3 or later <https://gnu.org/licenses/gpl.html>.
This is free software: you are free to change and redistribute it.
There is NO WARRANTY, to the extent permitted by law.

Written by Mike Parker, David MacKenzie, and Jim Meyering.
$ POSIXLY_CORRECT=1 rm a -i
Please run rm with -i/--interactive

Answer