☰

zshでgsettingsキーバインディングの配列値を自動的に割り当てます。

tag-icon • tag-icon zsh array gsettings
zshでgsettingsキーバインディングの配列値を自動的に割り当てます。

私はこのスクリプトがキーバインディングを設定する必要があると思いましたが、今はかなり退屈です。更新：廃棄され、今動作します。見苦しいですが、新しいキーバインディングが必要なときはいつでも4行をコピーして貼り付ける必要があるため、よりエレガントにする方法を探しています。

私はzshが2D配列をサポートしていないので、Pythonで書き換える方が良いと主張しました...更新後もPythonスクリプトはまだ存在します。ここ

キーバインディングを正しく設定する方法ここ。

#!/bin/zsh
# How many keybinds?
N=16
# Put keybindings here
k0=("keyboard dvorak nocaps" "Menu" "setxbmap dvorak -option nocaps")
k1=("launch code" "<Super>c" "code")
k2=("dropdown firefox" "<Shift><Super>f" "tdrop -ma -h \"100%\" -w \"50%\" firefox")

mkeys="org.gnome.settings-daemon.plugins.media-keys"
_locstr="/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom"
_ck="$mkeys.custom-keybinding:$_locstr"
M="$(expr $N - 1)"

# Create spaces for $N keybindings, emulating the command:
# gsettings set org.gnome.settings-daemon.plugins.media-keys custom-keybindings "['/org/gnome/settings-daemon/plugins/ media-keys/custom-keybindings/custom0/', '/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom1/ ']"
locations=""
for i in $(seq 0 $M); do
  locations+="'$_locstr$i/', "
done
locations+="'$_locstr$N/' "
gsettings set $mkeys custom-keybindings "[$locations]"


# issue commands. Have to paste 4 lines each time, kinda gross.
ck="${_ck}0/"
gsettings set $ck name    $k0[1]
gsettings set $ck binding $k0[2]
gsettings set $ck command $k0[3]
ck="${_ck}1/"
gsettings set $ck name    $k1[1]
gsettings set $ck binding $k1[2]
gsettings set $ck command $k1[3]
ck="${_ck}2/"
gsettings set $ck name    $k2[1]
gsettings set $ck binding $k2[2]
gsettings set $ck command $k2[3]

# test with:
# i=0
# ck="${_ck}$i/"
# gsettings get org.gnome.settings-daemon.plugins.media-keys custom-keybindings
# gsettings list-recursively $ck

答え1

改善できるいくつかの方法：

#! /bin/zsh -

bindings=(
  'keyboard dvorak nocaps' Menu              'setxbmap dvorak -option nocaps'
  'launch code'            '<Super>c'        code
  'dropdown firefox'       '<Shift><Super>f' 'tdrop -ma -h 100% -w 50% firefox'
)

mkeys=org.gnome.settings-daemon.plugins.media-keys
locstr=/${mkeys//./\/}/custom-keybindings/custom
ck=$mkeys.custom-keybinding:$locstr

locations=() i=0
for name binding command ($bindings) {
  for type (name binding command) gsettings set $ck$i $type ${(P)type}
  locations+=( "'$locstr$i'" )
  (( i++ ))
}

gsettings set $mkeys custom-keybindings "[${(j[, ])locations}]"

関連情報