☰

行または列の指定された位置に移動するには？

tag-icon • tag-icon emacs
行または列の指定された位置に移動するには？

ファイルを開くときに使用できます。

$ emacs +2:9 practice.b

これにより、「practice.b」ファイルの行2とその行の文字9が開きます。すでに実行しているEmacsでこれをジャンプするにはどうすればよいですか？わかりました。M-x goto-lineしかし、セミコロンを認識しません。

答え1

M-x goto-line（M-g gまたはM-g M-g）を使用すると、ターゲット行の先頭に移動します。その後、M-g | 8 RET（M-x move-to-column 8 RET）を使用してターゲット列に移動できます（C-u 8 rightワイド文字がない場合は機能します）。 Emacsは0から始まる列の番号を付けますが、コマンドラインオプションは+LINE:COLUMN1から始まる列の番号を付けるため、列8になります。

入力できるEmacsコマンドが必要な場合は、次の2:9コードのいくつかをファイルに貼り付けて引数.emacsとして書き込むことができますgoto-line。このコードはEmacs 23でのみ最小限にテストされています。

(defadvice goto-line (around goto-column activate)
  "Allow a specification of LINE:COLUMN instead of just COLUMN.
Just :COLUMN moves to the specified column on the current line.
Just LINE: moves to the current column on the specified line.
LINE alone still moves to the beginning of the specified line (like LINE:0)."
  (if (symbolp line) (setq line (symbol-name line)))
  (let ((column (save-match-data
                  (if (and (stringp line)
                           (string-match "\\`\\([0-9]*\\):\\([0-9]*\\)\\'" line))
                      (prog1
                        (match-string 2 line)
                        (setq line (match-string 1 line)))
                    nil))))
    (if (stringp column)
        (setq column (if (= (length column) 0)
                         (current-column)
                       (string-to-int column))))
    (if (stringp line)
        (setq line (if (= (length line) 0)
                       (if buffer
                         (save-excursion
                           (set-buffer buffer)
                           (line-number-at-pos))
                         nil)
                     (string-to-int line))))
    (if line
        ad-do-it)
    (if column
        (let ((limit (- (save-excursion (forward-line 1) (point))
                        (point))))
          (when (< column limit)
            (move-to-column column))))))

答え2

Emacs 24+では、Gilles関数が私には機能しなかったので、別のバージョンの関数を書いています（理由はわかりません）。

(defun go-to-line-and-column-cond (lc-cond)
  "Allow a specification of LINE:COLUMN or LINE,COLUMN instead of just COLUMN.                                                                                                              
Just :COLUMN or ,COLUMN moves to the specified column on the current line.                                                                                                                  
LINE alone still moves to the beginning of the specified line (like LINE:0 or LINE,0).                                                                                                      
By Default I'm bind it to M-g M-l.                                                                                                                                                          
The default value of the COLUMN is decrement by -1                                                                                                                                          
because all compilers consider the number of COLUMN from 1 (just for copy-past)"
  (interactive "sLine:Column:: ")
  (let (line delim column max-lines)
    (setq max-lines (count-lines (point-min) (point-max)))
    (save-match-data
      (string-match "^\\([0-9]*\\)\\([,:]?\\)\\([0-9]*\\)$" lc-cond)
      (setq line (string-to-number (match-string 1 lc-cond)))
      (setq delim (match-string 2 lc-cond))
      (setq column (string-to-number (match-string 3 lc-cond)))
      (if (not (equal delim "")) (if (> column 0) (setq column (1- column))))
      (if (= 0 line) (setq line (line-number-at-pos)))
      (if (> line max-lines) (setq line max-lines))
      (goto-line line)
      (move-to-column column)
      (message "Marker set to line %d column %s" (line-number-at-pos) (current-column))
      )))

(global-set-key (kbd "M-g M-l") 'go-to-line-and-column-cond)

答え3

努力するset-goal-column（C-x C-n）

関連情報