☰

シェル行の列の最後の値から最初の値を減算するには？

tag-icon • tag-icon shell sed awk perl
シェル行の列の最後の値から最初の値を減算するには？

次のデータファイルがあります。

1 1 1 1 1 1 1 1 2 2 2 2 3 3 3 3 3 3 
2 4 5 8 9 10 13 17 19 29 30 32 33 50 700 800 900 950

まず、3つの同じ値の間にスペースを挿入し、最初の行を見て3つの同じ数字を1つの列に配置しようとしています。

1 1 1  1 1 1  1 1  2 2 2  2  3 3 3  3 3 3 
2 4 5  8 9 10  13 17  19 29 30  32  33 50 700  800 900 950

次に、2行目の各新しい列の最後の値から最初の値を減算したい（ただし、特定の列（ここでは2行目の4列目）に値が1つしかない場合は、前の列の最後の最初の行の各列に固有です。 1つの数字を保持しながら、この値（32〜30）から値を減算する必要があります。したがって、最終データは次のようになります。

1 1 1 2 2 3 3
3 2 4 11 2 667 150

どんな提案がありますか？また、私の実際のデータが本当に大きく、最初の行で5つの固有値をグループ化したいことにも言及する必要があります。グループのサイズを変更したい場合があります。だからスクリプトは柔軟でなければなりません。

答え1

Perlが救出に来る！

#!/usr/bin/perl
use warnings;
use strict;

my $group_size = 3;

my @first = split ' ', <>;

my @groups;
my $start_index = 0;
while ($start_index < @first) {
    my $step = 1;
    while ( $step < $group_size
            && $start_index + $step < @first
            && $first[$start_index] == $first[ $start_index + $step ]
          ) {
        ++$step;
    }
    push @groups, $step;
    print $first[$start_index], ' ';
    $start_index += $step;
}
print "\n";

my @numbers = split ' ', <>;

my $last;
for my $size (@groups) {
    my @group = splice @numbers, 0, $size;
    my $value = $group[-1] - $group[0];
    $value = $group[0] - $last if 1 == $size;
    $last = $group[-1];
    print $value, ' ';
}
print "\n";

最初のグループにメンバーが1つしかない場合はどうなるかを指定していません。

答え2

これはチョロバの答えに似ています

$ cat file
1 1 1 1 1 1 1 1 2 2 2 2 3 3 3 3 3 3 
2 4 5 8 9 10 13 17 19 29 30 32 33 50 700 800 900 950 

$ perl -ane '
    if ($. == 1) {
        for (($n,$i,$j) = (1,0,0); $j < @F; $n++, $j++) {
            if ($n == 3 || $F[$j] != $F[$j+1]) {
                $i-- if $i == $j;
                push @pairs, [$i, $j];
                $n = 0;
                $i = $j + 1;
            }
        }
        printf "%d ", $F[ $_->[1] ] for @pairs;
    }
    else {
        printf "%d ", $F[ $_->[1] ] - $F[ $_->[0] ] for @pairs;
    }
    print "\n";
' < file
1 1 1 2 2 3 3 
3 2 4 11 2 667 150

入力の最初の行は、関心のある($. == 1)インデックスペアのリストを計算します。これにより、次のようになります。

[[0, 2], [3, 5], [6, 7], [8, 10], [10, 11], [12, 14], [15, 17]]

関連情報