☰

ls出力を変更せずにAIXでファイル所有者を取得する方法は？

tag-icon • tag-icon files aix stat
ls出力を変更せずにAIXでファイル所有者を取得する方法は？

どうやってできるか安定してAIXでファイルの所有者を取得しますか？安定して、私はls。stat --printf=%U foo私はこれができることを知っていますが、istatAIXにはオプションがないため、まだ出力を使用して処理する必要があるため、理想的ではありません。つまり、AIXのコアユーティリティのみを使用してLinuxをどのようにエミュレートしますか？--printfistatgrepawkstat --printf=%U foo

答え1

これは、AIXでstat（1）に似たユーティリティーを取得するためにしばらく前に作成したスクリプトです。今％Uを追加しました！ --printfとは少し異なる動作をする-cオプションを使用する方が便利です。 Perl統計配列の便利なローカルコピーをコメントブロックとして含めます。

#!/usr/bin/env perl -w
# emulate GNU coreutils stat command in a limited way
# -- only implemented a subset of the stat() options

use strict;
use Getopt::Std;
our $opt_c;

getopts('c:') or die "Usage: $0 [ -c (%n %i %u %g %s %U %X %Y %Z) ] file ...";
# default format is empty (not useful, but avoids 'undef' errors later)
$opt_c |= '';

for (@ARGV) {
  my @s = stat;
  next unless @s; # silently fail on to the next file
  my $p = $opt_c; # make a copy of the format string to mangle for each file

  # mangle and print
  $p =~ s/%n/$_/g;
  $p =~ s/%i/$s[1]/g;
  $p =~ s/%u/$s[4]/g;
  $p =~ s/%g/$s[5]/g;
  $p =~ s/%s/$s[7]/g;
  $p =~ s/%U/getpwuid($s[4])/eg;
  $p =~ s/%X/$s[8]/g;
  $p =~ s/%Y/$s[9]/g;
  $p =~ s/%Z/$s[10]/g;
  print "$p\n";

  #                 0 dev      device number of filesystem
  #                 1 ino      inode number
  #                 2 mode     file mode  (type and permissions)
  #                 3 nlink    number of (hard) links to the file
  #                 4 uid      numeric user ID of file's owner
  #                 5 gid      numeric group ID of file's owner
  #                 6 rdev     the device identifier (special files only)
  #                 7 size     total size of file, in bytes
  #                 8 atime    last access time in seconds since the epoch
  #                 9 mtime    last modify time in seconds since the epoch
  #                10 ctime    inode change time in seconds since the epoch (*)
  #                11 blksize  preferred block size for file system I/O
  #                12 blocks   actual number of blocks allocated

}

関連情報