☰

パターンに一致する行を別のファイルの行に順次置き換える

tag-icon • tag-icon text-processing files sed awk perl
パターンに一致する行を別のファイルの行に順次置き換える

たとえば、次のように、あるファイルのパターンに一致する行を別のファイルから順番に置き換えたいとします。

ファイル1.txt:

aaaaaa
bbbbbb
!! 1234
!! 4567
ccccc
ddddd
!! 1111

!!で始まる行を次のファイルに置き換えるのが好きです。

ファイル2.txt:

first line
second line
third line

したがって、結果は次のようになります。

aaaaaa
bbbbbb
first line
second line
ccccc
ddddd
third line

答え1

簡単にできるアッ

awk '
    /^!!/{                    #for line stared with `!!`
        getline <"file2.txt"  #read 1 line from outer file into $0 
    }
    1                         #alias for `print $0`
    ' file1.txt

その他のバージョン

awk '
    NR == FNR{         #for lines in first file
        S[NR] = $0     #put line in array `S` with row number as index 
        next           #starts script from the beginning
    }
    /^!!/{             #for line stared with `!!`
        $0=S[++count]  #replace line by corresponded array element
    }
    1                  #alias for `print $0`
    ' file2.txt file1.txt

答え2

GNU sed似ているawk+getline

$ sed -e '/^!!/{R file2.txt' -e 'd}' file1.txt
aaaaaa
bbbbbb
first line
second line
ccccc
ddddd
third line
  • R一度に1行ずつ与えられる
  • 順序が重要です最初、R最後d


そしてperl

$ < file2.txt perl -pe '$_ = <STDIN> if /^!!/' file1.txt
aaaaaa
bbbbbb
first line
second line
ccccc
ddddd
third line
  • <STDIN>ファイルハンドルを使用して読み取れるように、代替行を含むファイルを標準入力に渡します。
  • 一致する行が見つかったら、$_標準入力の行に置き換えます。

関連情報