☰

熱のマージと追加

tag-icon • tag-icon text-processing awk columns merge
熱のマージと追加

次の内容を含むファイルがあります（最初の列を埋める余分なスペースを含む）。

  1 account1 192.168.0.1  
  1 account1 192.168.0.2   
 19 account2 192.168.0.1   
100 account3 192.168.0.3   
  1 account3 192.168.0.5

次の出力を取得しようとしています。

  2 account1 192.168.0.1, 192.168.0.2  
 19 account2 192.168.0.1  
101 account3 192.168.0.3, 192.168.0.5

私はそれを繰り返して、アカウントに電子メールを送信するHTMLテーブルを作成します。次のコマンドを使用して各アカウントのIPリストを取得しました。

awk '{a[$2]=a[$2]" " $3}END{for (i in a) print i" " a[i]}' inputfile

ただし、最初の列も合計できません。

答え1

合計をスクリプトに追加することはそれほど難しくありません。合計を保存する別の配列を追加するだけです。

$ awk '{ if (a[$2]) a[$2] = a[$2] ", ";
         a[$2] = a[$2] $3;
         sum[$2] += $1 }
       END {for (x in a) printf "%3d %s %s\n", sum[x], x, a[x]}' inputfile
  2 account1 192.168.0.1, 192.168.0.2
 19 account2 192.168.0.1
101 account3 192.168.0.3, 192.168.0.5

（例出力のIPアドレスはカンマで区切られているため、これを追加しました。しかし、少なくともIPアドレスがないと、コードはよりきれいに見えます。）

答え2

Awk解決策：

awk 'NR==1{ match($0, /^ +[^ ]+/); s=length(substr($0, RSTART, RLENGTH)) }
     { sum[$2]+=$1; ips[$2]=($2 in ips? ips[$2]", ":"")$3 }
     END{ 
         for (i in sum) 
             printf("%*s %s %s\n", s, sum[i], i, ips[i]) 
     }' file

出力：

  2 account1 192.168.0.1, 192.168.0.2
 19 account2 192.168.0.1
101 account3 192.168.0.3, 192.168.0.5

答え3

私はおそらくこれを考えすぎているでしょう。 （おそらく使用するのに良いawk / sedがあるでしょう）これが私が思いつくことができる最善です：

#!/bin/bash
# set file as sys argument
file=$1

# pull unique account names into an array
account_names=($(awk '{print $2}' $file | sort | uniq))

# loop through and store column values
for account in ${account_names[@]}; do
    # get a sum of the first column
    col1=$(grep $account $file | awk '{SUM += $1} END {print SUM}')
    # get last column and convert to one line with comma separation
    IP_list=$(grep $account $file | awk '{print $NF}' | sort | uniq | tr '\n' ',' | sed s'/.$//')
    # print them together
    echo "$col1 $account $IP_list"
done

その後、次のように実行できます。

┌─[robotjohny@Fedora]─[~]─[04:08 pm]
└─[$]› ./test1.sh file1.txt 
2 account1 192.168.0.1,192.168.0.2
19 account2 192.168.0.1
101 account3 192.168.0.3,192.168.0.5

関連情報