☰

データ列内の範囲の最大値、平均値、最小値

tag-icon • tag-icon text-processing awk numeric-data
データ列内の範囲の最大値、平均値、最小値

私のデータ構造は次のとおりです。

X   43808873    A   14
X   43808874    G   7
X   43808875    T   15
X   43808876    A   13
X   43808877    T   4
X   43808878    C   13
X   43808879    T   11
X   43808880    C   8
X   43808881    T   3
X   43808882    C   14
X   43808883    T   15
X   43808884    C   15

4列の最大値、最小値、および平均を計算できるようにしたいが、特定の範囲（43808877-43808882など）内でのみ可能です。

このawkコードがありますが、特定の範囲に対して変更する方法がわかりません。どんな提案でもいただければ幸いです。

awk 'NR == 1 { min = $4; max = $4 }
   {
    sum += $4
    if ($4 > max) {
        max = $4
    }
    if ($4 < min) {
        min = $4
    }
   } END {
    print max
    print min
    print sum / NR
   }' file

答え1

一方通行：

sort -k4n,4 file | awk '$2>=43808877 && $2<=43808882{tot+=$4;cnt++;max=$4;min=cnt==1?$4:min}END{print min, max,tot/cnt}'

まずsort、最初のレコードが最小値を持ち、最後のレコードが最大値を持つようにファイルを4列に配置します。を使用してawk範囲の数を合計し、統計を印刷します。

答え2

awkが好きではない場合、Millerはこの種の作業に適しています。

mlr --nidx --repifs filter '$2 >= 43808877 && $2 <= 43808882' then stats1 -f 4 -a max,min,mean file

答え3

$ cat tst.awk
$2>=43808877 && $2<=43808882 {
    cnt++
    sum += $4
    min = ( (cnt == 1) || ($4 < min) ? $4 : min )
    max = ( (cnt == 1) || ($4 > max) ? $4 : max )
}
END {
    print max+0
    print min+0
    print (cnt ? sum / cnt : 0)
}

$ awk -f tst.awk file
14
3
8.83333

目的の範囲内にレコードがない場合でも、常に数値出力を取得し、ゼロ除算エラーが発生しないようにENDセクションのガードに注意してください。

答え4

ライトバージョン。

$ awk '/43808877/,/43808882/{t+=$4;c++;if($4>x){x=$4}if($4<n||!length(n)){n=$4}}END{print x,n,t/c}' f
14 3 8.83333
$

関連情報