☰

テキストファイルからタイトルサブストリングに一致する列を抽出する

tag-icon • tag-icon awk
テキストファイルからタイトルサブストリングに一致する列を抽出する

ヘッダー（最初の行）が他のテキストファイル「string」にリストされている部分文字列と一致するテキストファイル「columns.txt」からタブ区切りの列を抽出したいと思います。
「columns.txt」は次のようになります。

A   B   C   D   E   F   rs243_A   rs546_G   rs987_T   rs025_C   ...
A   B   C   D   E   F   0         0         0         1         ...
A   B   C   D   E   F   1         1         2         2         ...
A   B   C   D   E   F   0         1         2         0         ...
... ... ... ... ... ... ...       ...       ...       ...       ...

"strings.txt"は次のとおりです。

rs243
rs987  
...

出力テキストファイルは、「columns.txt」から列1〜6をコピーし、「strings.txt」で指定された抽出されたすべての列（タブ区切り）を追加する必要があります。出力ファイル「output.txt」は次のようになります。

A   B   C   D   E   F   rs243   rs987   ...
A   B   C   D   E   F   0       0       ...
A   B   C   D   E   F   1       2       ...
A   B   C   D   E   F   0       2       ...
... ... ... ... ... ... ...     ...     ...

私が使用するコードは、1〜6列を "output.txt"に印刷しますが、抽出された列を追加しません。

awk -F '\t' -f /data/p_00614/ABCD/scripts/extract.awk /data/strings.txt /data/columns.txt > /data/output.txt

"extract.awk"の使用：

BEGIN { OFS = FS }

FNR == NR {
    sub("_.*", "", $1)
    columns[$1] = 1
    next
}

FNR == 1 {
    for (i = 1; i <= NF; ++i)
        if (i <= 6 || $i in columns)
            keep[i] = 1
}

{
    nf = split($0, fields, FS)
    $0 = ""
    j = 0

    for (i = 1; i <= nf; ++i)
        if (i in keep)
            $(++j) = fields[i]

    print 
}

私の考えでは

sub("_.*", "", $1)

動作しません。"_.*"最初からすべての部分文字列を切り取ることはできませんが、_正確に一致する部分だけを切り取ることができます。この問題を解決する方法に関する提案はありますか？ありがとうございます！

答え1

これは私が提供したコードのバグです。あなたの質問の1つに対する以前の回答（今は修正されました）。この_.*ビットは読み取っている文字列から削除しないでください。読み取ってstrings.txtいるデータから削除する必要がありますcolumns.txt。

修正されたスクリプト：

BEGIN { OFS = FS }

FNR == NR {
    columns[$1] = 1
    next
}

FNR == 1 {
    for (i = 1; i <= NF; ++i) {
        sub("_.*", "", $i)
        if (i <= 6 || $i in columns)
            keep[i] = 1
    }
}

{
    nf = split($0, fields, FS)
    $0 = ""
    j = 0

    for (i = 1; i <= nf; ++i)
        if (i in keep)
            $(++j) = fields[i]

    print 
}

FNR == NR質問のブロックがわずかに変更されていることを確認してください。FNR == 1

関連情報