☰

あるファイルのインデックス値を使用して印刷し、2番目のファイルからデータを抽出し、出力を3番目のファイルに保存するにはどうすればよいですか？

tag-icon • tag-icon text-processing awk
あるファイルのインデックス値を使用して印刷し、2番目のファイルからデータを抽出し、出力を3番目のファイルに保存するにはどうすればよいですか？

次の2つのファイルがあります。

# File 1 has 3 columns:
SampleName   Type     Position
5R01924      ABC      92184093
5R01028      ABC      15589809
5R01092      ABC      48759348

# File 2 has many columns. 
# Column 2 is the Position 
# Columns 5 to end are the different SampleNames
A   Position   B    C    5R01924       5R01028       5R01092 
1   15589809   2    3    D:E:F:G       H:I:J:K       L:M:N:O
1   92184093   2    3    P:Q:R:S       T:U:V:W       X:Y:Z:AA
1   48759348   2    3    AB:AC:AD:AE   AF:AG:AH:AI   AJ:AK:AL:AM

最初のファイルに4番目の列を追加するか、ファイル1をコピーして、この新しい3番目のファイルに4番目の列を追加したいと思います。

列4には、ファイル1のインデックスを使用してファイル2から抽出された正しい情報を含める必要があります。したがって、ファイル1の行1は、ファイル2の行2に移動して列5（5R01924）から情報を抽出することを意味します。しかし、私はこの情報のR部分だけが欲しいです。したがって、出力は次のようになります。

# file 3 or append column 4 to file 1
SampleName   Type     Position     Output
5R01924      ABC      92184093     R
5R01028      ABC      15589809     J
5R01092      ABC      48759348     AL

これまで、私は次のようなものを持っています：

while IFS=" " read -r value1 value2 value3
do
        awk '$2 == "${value3}" {
        # find column # from name of value 1 (save as col variable) 
        print split(${col},a,":"), a[3]
        }' file2 >> file3.txt
done
# where does file 1 go?

助けてください:)

答え1

awkはそれを自分で処理できます。ここに "combine.awk"ファイルがあります。

# first file, first line
FILENAME == ARGV[1] && FNR == 1  {
    for (i=5; i<=NF; i++) head[i] = $i
}

# first file,  subsequent lines
FILENAME == ARGV[1] && FNR > 1 {
    for (i=5; i<=NF; i++) {
        split($i, f, /:/)
        value[$2, head[i]] = f[3]
    }
}

# second file
FILENAME == ARGV[2] {
    print $0, (FNR == 1 ? "Output" : value[$3, $1])
}

それではこう呼びます。

awk -f combine.awk file2 file1 > file3

出力ファイルには以下が含まれます。

SampleName   Type     Position Output
5R01924      ABC      92184093 R
5R01028      ABC      15589809 J
5R01092      ABC      48759348 AL

答え2

ファイルを読み取るためにbashを呼び出す必要はありません。

私たちはこれらすべてをawkで次のようにすることができます：

### sanitize inputs
for f in ./File1 ./File2; do
  dos2unix "$f"
done

awk '
  !NF || $1 ~ /^#/ {next}
  NR==FNR {
    for (i=5; i<=NF; i++)
      if (NR > 1) {
        split($i, t, /:/)
        a[sample[i-4],$2] = t[3]
        split("", t, ":")
      }
      else sample[i-4] = $i
    next
  }
  {
    k = $1 SUBSEP $3
    f = FNR == 1  ? "Output" \
      : !(k in a) ? "N/A"    \
      : a[k]
    print $0, f
  }
' File2 OFS="\t" File1

出力：

SampleName   Type     Position  Output
5R01924      ABC      92184093  R
5R01028      ABC      15589809  J
5R01092      ABC      48759348  AL

答え3

まず、あなたの質問は複雑なので、簡単な答えを期待することはできません。

awk 'BEGIN{IFS="[[:space:]]+";OFS=" ";} NR>1 && NR==FNR {Trr[$3]=$0;Arr[$1]=$3;next} NR>FNR && FNR==1 {for(key in Arr) {for(i=5;i<=NF;i++) {if(key==$i) {nArr[key]=i;break}}}} NR>FNR && FNR>1 {for(tKey in Trr) {if($2==tKey) {for(aKey in Arr) {if(Arr[aKey]==$2) {i=nArr[aKey];Trr[tKey]=Trr[tKey]" "$i;break}}}}}END{for(key in Trr) print Trr[key]}' A B | tr ':' ' ' | awk -F'[[:space:]]+' '{print $1,$2,$3,$6}'

上記の説明：

  • IFSそしてオルフェウス：入出力ファイル区切り記号です。
  • [[:space:]]+: ファイル区切り文字に複数のスペースがあるため、これを使用する必要があります。
  • NRはい行番号最初から...
  • FNR: はいファイル行番号です。複数のファイル名を指定するawk場合NRしかし、1から始めてFNRファイル変更で1にリセット
  • 次へ、残り非常に明確な
  • {}：通訳の混乱を防ぐために、すべてのブロックでこれを使用する必要があります。

関連情報