ifconfigからインターフェイス名、ハードウェアアドレス、およびIPアドレスを抽出する（ipコマンドの代わりにifconfigを使用する必要があります）

awk 'BEGIN { OFS="\t" }; # use tab for output separator

     ! /^ / {   # line doesnt begin with a space, must be an interface line, extract it
       i=gensub(/:$/,"",1,$1)
       mac[i]=$5;     # this will either be a HWAddr or empty
       ifaces[i]=1
     };

     /^ +inet/ { ip[i] = ip[i] " " gensub(/addr:/,"",1,$2) };

     /^ +ether/ { mac[i]=$2};  # this will only match if there WASNT a HWAddr on the iface line

     END {
       for (i in ifaces) {
         sub(/^ +/,"",ip[i]); # remove unwanted space from beginning of ip addresses
         #if (ip[i]  == "") ip[i]  = "--"; #optional
         #if (mac[i] == "") mac[i] = "--"; #optional
         print i, ip[i], mac[i]
       }
     }' filename | sort

ifconfig（または入力ファイル名を指定する代わりに入力をパイプするだけです。）

このawkスクリプトはifconfig出力バリアントを処理し、タブ区切りの3つのフィールド（インターフェース名、IPアドレス、およびMACアドレス）を出力できます。

2番目のフィールドに複数のIPアドレスがある場合は、スペースで区切ります。

input1に対して実行され、次にパイプされたときの出力sort：

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1

input2に対して実行され、次にパイプされたときの出力sort：

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0            00:50:56:00:00:00
eth1            00:50:56:00:00:00
lo      127.0.0.1

注：要求された出力にはbond0：0のIPアドレスとして192.168.0.2がありますが、サンプルデータにはインターフェースと同じ192.168.0.1がありますbond0。

スクリプトから「オプション」行のコメントを外すと、IPアドレスまたはMACアドレスフィールドが空であっても、タブ区切りの出力フィールドが常に3つあることを確認します。

出力は次のとおりです。

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1       --

そして

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0    --      00:50:56:00:00:00
eth1    --      00:50:56:00:00:00
lo      127.0.0.1       --

---

追加コメント：

これは間違いこのipコマンドを無視してください。これは長年のLinuxの標準であり、セカンダリ/代替/「エイリアス」IPアドレスをインターフェイスに追加する多くのプログラムで使用されています。このようにインターフェイスに追加されたセカンダリIPアドレスは、ただと表示され、ip addr show実行時には表示されません。ifconfig

ifconfig少なくともLinuxでは、従来と見なされるべきです。

ifconfig単純だが効果的な解決策は、出力を逆に読み取ることです。ブロックの最初の行に出会うたびに、関心のあるフィールドを見つけたか、そのフィールドが見つからないと安全に想定できます。 AWKスクリプトが与えられた場合：

{
  for (i = 1; i  <= NF; i++) {
    if ($i == "inet") {
      ip = $(i+1)
      sub(/.*:/, "", ip)
    }
    if ($i == "HWaddr" || $i == "ether")
      hw = $(i+1)
  }
}
/^[^[:blank:]]/ {
  nm = $1
  sub(/:$/, "", nm)
  print nm,ip,hw
  nm = ""
  ip = ""
  hw = ""
}

として保存すると仮定すると、awkscript次のことができます。

ifconfig | tac | awk -f awkscript | tac | column -s ' ' -t

非標準tacコマンドが利用できない場合は、このAWKスクリプトを簡単に変更して、入力ストリーム全体を配列に保存してENDブロックから逆処理できます。

$ cat tst.awk
!/^[[:space:]]/ { if (NR>1) prt() }
{ rec = rec FS $0 }
END { prt() }

function prt(   flds,i,nf,map) {
    sub(/: /," ",rec)
    sub(/ ether /," HWaddr ",rec)
    sub(/ inet addr:/," inet ",rec)

    nf = split(rec,flds)
    map["iface"] = flds[1]
    for (i=2; i<nf; i++) {
        map[flds[i]] = flds[i+1]
    }
    print map["iface"], map["inet"], map["HWaddr"]

    rec = ""
}

$ awk -f tst.awk file1 | column -s' ' -t
eno16780032  192.168.0.1  00:50:56:00:00:00
eno33559296  192.168.0.2  00:50:56:00:00:01
lo           127.0.0.1

$ awk -f tst.awk file2 | column -s' ' -t
bond0    192.168.0.1  00:50:56:00:00:00
bond0:0  192.168.0.1  00:50:56:00:00:00
eth0                  00:50:56:00:00:00
eth1                  00:50:56:00:00:00
lo       127.0.0.1