☰

zsh 空行でタブを完成

tag-icon • tag-icon shell configuration zsh
zsh 空行でタブを完成

私は見つけることができないtcsh'ismが欲しいです。内容のない空の行でtabを押してlsと同等のものを見たいと思います。つまり私が欲しい

$ <tab>

別のことをして私にa \ tを与えてください。コマンドを完了するための優れたリソースが見つかりましたが、この基本的なケースでは機能しません。これに対するどんな助けでもいいでしょう！ありがとうございます。

答え1

行の先頭の動作Tab理由insert-tab スタイル。ただし、サポートされる動作は 2 つしかありません。

  • いつものように完了してください。zstyle ':completion:*' insert-tab false
  • 下にタブを挿入してくださいzstyle ':completion:*' insert-tab true
  • 次のいずれかzstyle ':completion:*' insert-tab pending[=N]

その場所でコマンドを完了したい場合はzstyle ':completion:*' insert-tab true大丈夫です。現在のディレクトリにあるファイルを一覧表示するなど、他のものが必要な場合は_main_complete。

ㅏzsh-workersリストの最新トピック議論insert-tab。

答え2

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

答え3

これは、空の行でタブをクリックしたときにzshからtcshの自動リストを完全に実装したものです。

% <TAB>

ここにいる：

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

tcsh をさらにエミュレートするには、.zshrc に以下を追加します。

unsetopt always_last_prompt       # print completion suggestions above prompt

答え4

私は書いたこれzshウィジェットは、空白行だけでなくコマンドを入力するときでもTABの使用を改善します。

  • それはリストされています文書空のコマンドラインとコマンドの中間にあります。
  • それはリストされています目次空のコマンドラインに。
  • それはリストされています実行可能ファイル空のコマンドラインに。

このような場合は、「cd」または「./」が前に付けられたグローバル変数を使用するように設定できます。

export TAB_LIST_FILES_PREFIX

tab_list_files_example

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA

関連情報