☰

ファイルの2つのタグの間にあるすべてのコンテンツをどのように削除しますか？

tag-icon • tag-icon text-processing sed awk perl
ファイルの2つのタグの間にあるすべてのコンテンツをどのように削除しますか？

\{{[}テキストファイルにテキストがあり、文字列自体を含むなどの文字列の間にあるすべての内容を削除したいと思います。{]}\}これら2つの文字列できる別の行にあり、同じ行にあります。どちらの場合も、 存在する先頭がある行\{{[}、その前のテキストが削除されることを望まない。つまり、左のテキスト - 後のテキストも同じです{]}\}。

例は次のとおりです。コンテンツを含むテキストファイルが提供されます。

Bla Bla bla bla \{{[} more bla bla
even more bla bla bla bla. 

A lot of stuff might be here.

Bla bla {]}\} finally done.

Nonetheless, the \{{[} show {]}\} goes on.

スクリプトは、コンテンツを含む他のテキストファイルを返す必要があります。

Bla Bla bla bla  finally done.

Nonetheless, the  goes on.

残念ながら、単純に見えるこの作業は私にとってとても難しかったですsed。私はとても幸せですどの標準のLinuxシステムに何もインストールする必要がない限り、すべての言語ソリューション（Cおよび一部のJavaがすでにインストールされています）。

答え1

そしてperl：

perl -0777 -pe 's/\Q\{{[}\E.*?\Q{]}\}\E//gs'

フル入力は処理前にメモリにロードされます。

\Qsomething\Esomething正規表現ではなくリテラル文字列として扱われます。

一般ファイルを変更するには、次の-iオプションを追加します。

perl -0777 -i -pe 's/\Q\{{[}\E.*?\Q{]}\}\E//gs' file.txt

GNUを使用するawkか、次のようにしますmawk。

awk -v 'RS=\\\\\\{\\{\\[}|\\{\\]}\\\\}' -v ORS= NR%2

そこで私達は定義します記録区切り記号開始タグまたは終了タグのいずれかとして使用されます（正規表現はここでのみサポートされていますgawk）mawk。RSしかし、再び正規表現演算子の文字（バックスラッシュ{、、、）[とバックスラッシュをエスケープする必要があります。なぜなら、バックスラッシュは引数( , ...-vのようなものに使われる ) に特殊なのでバックスラッシュがたくさんあるからです。\n\b

それから私たちがしなければならないのは、他のすべてのレコードを印刷することだけです。すべての奇数レコードについてNR%2（true）。1

どちらのソリューションもタグが一致し、部品が入れ子になっていないと仮定します。

最新バージョンのGNUを使用してファイルを変更するには1オプションをawk追加します。-i /usr/share/awk/inplace.awk

^使用しないでください-i inplace現在の作業ディレクトリから最初に拡張機能をgawkロードしようとすると、誰かがそのディレクトリにマルウェアを植えた可能性があります。システムに付属の拡張プログラムのパスは異なる場合があります。出力を参照してください。inplaceinplaceinplace.awkinplacegawkgawk 'BEGIN{print ENVIRON["AWKPATH"]}'

答え2

sed   -e:t -e'y/\n/ /;/\\{{\[}/!b'               \
      -e:N -e'/\\{{\[.*{\]}\\}/!N'               \
           -e's/\(\\{{\[}\).*\n/\1/;tN'          \
           -e'y/ /\n/;s/\\{{\[}/& /;ts'          \
      -e:s -e's/\(\[} [^ ]*\)\({\]}\\}\)/\1 \2/' \
      -ets -e's/..... [^ ]* .....//;s/ //g;bt'   \
<<""
#Bla Bla {]}\} bla bla \{{[} more bla bla
#even more bla bla bla bla. \{{[} 
#
#A lot of stuff might be here.
#hashes are for stupid syntax color only
#Bla bla {]}\} finally {]}\} done.
#
#Nonetheless, the \{{[} show {]}\} goes \{{[} show {]}\} on.

#Bla Bla {]}\} bla bla  finally {]}\} done.
#
#Nonetheless, the  goes  on.

しかし、より良い方法があります。代替項目ははるかに少なく、.*常に使用するのではなく、一度に数文字ずつ使用してください。実際に.*これが使用される唯一のケースは、最初に発生する開始が最初の後続の端と確実にペアになって中間のパターン空間を消去するときです。残りの時間は、次の区切り文字に達するためにできるだけ多く削除しますsed。Dお金が教えてくれました。

sed -etD -e:t -e'/\\{{\[}/!b'  \
    -e's//\n /;h;D'       -e:D \
    -e'/^}/{H;x;s/\n.*\n.//;}' \
    -ett    -e's/{\]}\\}/\n}/' \
    -e'/\n/!{$!N;s//& /;}' -eD \
<<""
#Bla Bla {]}\} bla bla \{{[} more bla bla
#even more bla bla bla bla. \{{[} 
#
#A lot of stuff might be here.
#hashes are for stupid syntax color only
#Bla bla {]}\} finally {]}\} done.
#
#Nonetheless, the \{{[} show {]}\} goes \{{[} show {]}\} on.

#Bla Bla {]}\} bla bla  finally {]}\} done.
#
#Nonetheless, the  goes  on.

ただし、RHS\n改行文字は文字通りバックスラッシュでエスケープされた改行文字に置き換える必要があります。

より一般的なバージョンは次のとおりです。

#!/usr/bin/sed -f
####replace everything between START and END
   #branch to :Kil if a successful substitution
   #has already occurred. this can only happen
   #if pattern space has been Deleted earlier
    t Kil
   #set a Ret :label so we can come back here
   #when we've cleared a START -> END occurrence
   #and check for another if need be
    :Ret
   #if no START, don't
    /START/!b
   #sigh. there is one. get to work. replace it
   #with a newline followed by an S and save
   #a copy then Delete up to our S marker.
    s||\
S|
    h;D
   #set the :Kil label. we'll come back here from now
   #on until we've definitely got END at the head of
   #pattern space.
    :Kil
   #do we? 
    /^E/{
       #if so, we'll append it to our earlier save
       #and slice out everything between the two newlines
       #we've managed to insert at just the right points        
        H;x
        s|\nS.*\nE||
    }
   #if we did just clear START -> END we should
   #branch back to :Ret and look for another START
    t Ret
   #pattern space didnt start w/ END, but is there even
   #one at all? if so replace it w/ a newline followed
   #by an E so we'll recognize it at the next :Kil
    s|END|\
E|
   #if that last was successful we'll have a newline
   #but if not it means we need to get the next line
   #if the last line we've got unmatched pairs and are
   #currently in a delete cycle anyway, but maybe we
   #should print up to our START marker in that case?
    /\n/!{
       #i guess so. now that i'm thinking about it
       #we'll swap into hold space, and Print it
        ${  x;P;d
        }
       #get next input line and add S after the delimiting
       #newline because we're still in START state. Delete
       #will handle everything up to our marker before we
       #branch back to :Kil at the top of the script
        N
        s||&S|
    }
   #now Delete will slice everything from head of pattern space
   #to the first occurring newline and loop back to top of script.
   #because we've definitely made successful substitutions if we
   #have a newline at all we'll test true and branch to :Kil 
   #to go again until we've definitely got ^E
    D

...コメントはありません...

#!/usr/bin/sed -f
    t Kil
    :Ret
    /START/!b
    s||\
S|
    h;D
    :Kil
    /^E/{
        H;x
        s|\nS.*\nE||
    }
    t Ret
    s|END|\
E|
    /\n/!{
        ${  x;P;d
        }
        N
        s||&S|
    }
    D

注釈付きバージョンをクリップボードにコピーし、次の操作を行います。

{ xsel; echo; } >se.sed
chmod +x se.sed
./se.sed <se.sed

#!/usr/bin/sed -f
####replace everything between
   #branch to :Kil if a successful substitution
   #has already occurred. this can only happen
   #if pattern space has been Deleted earlier
    t Kil
   #set a Ret :label so we can come back here
   #when we've cleared a  occurrence
   #and check for another if need be
    :Ret
   #if no  at the head of
   #pattern space.
    :Kil
   #do we?
    /^E/{
       #if so, we'll append it to our earlier save
       #and slice out everything between the two newlines
       #we've managed to insert at just the right points
        H;x
        s|\nS.*\nE||
    }
   #if we did just clear  we should
   #branch back to :Ret and look for another , but is there even
   #one at all? if so replace it w/ a newline followed
   #by an E so we'll recognize it at the next :Kil
    s|END|\
E|
   #if that last was successful we'll have a newline
   #but if not it means we need to get the next line
   #if the last line we've got unmatched pairs and are
   #currently in a delete cycle anyway, but maybe we
   #should print up to our

答え3

ファイルがtest.txtの場合は、次のものを使用できます。

sed ':a;N;$!ba;s/\n/ /g' test.txt|sed 's/\\{{\[}.*{\]}\\}//'

最初の sed はすべての改行を削除し、2 番目の sed はタグ内のテキストを削除します。

もっと一般的な解決策が必要かどうかわかりません。

関連情報